MS-VB 초급과정 3

이 강좌의 저작권은 월간 CD-Magazine에 있습니다. 배포 등의 행위를 금합니다. 이 강좌의 HTML 저작권은 Bluet에게 있습니다.

시작하면서...

필자에게는 좀 힘든 한달이었다. 여러분들은 어땠는지... 월드컵의 열기에 여름날의 더위가 합쳐져 지치고 축 늘어 지는 날이기도 했다. 특히 한국의 패배는 더욱 힘을 빠지게 했다. 축구도 평소의 투자와 노력이 있어야 하는 것. 다른 일도 마찬가지이며 비베도 예외일 수는 없다. 여러분들은 장인정신을 갖고 평소 실력을 갈고 닦는데 힘쓰기 바란다.

Do Loop 순환문
깜박거리는 폼
RGB 칼라
스크롤바
색상코드 생성기 1
색상코드 생성기 2
메뉴 다루기
텍스트박스
폼
폰트
텍스트 편집기 1
프로시져(서브, 함수)
인수전달 방법
클립보드
텍스트 편집기 2
팝업메뉴 만들기

저번 강좌에서 For Next 순환문을 잠깐 사용했었다. For Next문은 일정한 횟수 만큼 For와 Next 사이의 코드를 실행했었다. 그러나 항상 얼마만큼 반복해야 하는지 알 수 있는 것은 아니다. 때로는 그것을 전혀 모르는 때도 있 다. 힘들게나마 For Next문으로도 이러한 상황을 해결할 수 있으나 완벽한 해결책은 아니다. 이러한 경우에 사용 할 수 있는 Do Loop 순환문이 준비되어 있다. Do Loop문은 횟수에 의해 결정되지 않고 일정한 조건을 만족 시킬 때 까지 Do와 Loop 사이의 코드를 실행시킨다. Do Loop문은 약간씩 사용법이 다르다. 아래는 VB Help의 Do Loop문에 대한 설명이다.

Do [{While | Until} condition] [code] [Exit Do] [code] Loop

또는

Do [code] [Exit Do] [code] Loop [{While | Until} condition]

code: 실행시킬 VB 명령어나 함수 같은 코드들.

condition: Do Loop문을 끝낼 조건

Exit Do: 이 명령을 만나면 condition에 관계없이 무조건 Do Loop를 탈출한다(Loop 다음 문장으로 건너 뛴다).

While: While을 쓰면 condition이 참이면 Do Loop를 계속 실행한다. - 거짓이 될 때 까지 Do Loop를 실행한다.

Until: Until을 쓰면 condition이 참이 될 때 까지 Do Loop를 실행한다. While과 Until은 무엇을 사용해도 별 차이가 없다. While True와 같은 조건은 Until Not True와 같은 뜻이 된다. 하지만 아무래도 우리나라 사람 들의 정서상 Until이 더 이해하기 쉬운 것 같다.

Do Loop문은 조건을 어디에 써 주느냐에 따라 또 차이가 있다. 만약 Do 옆에 조건을 써 주면 Do Loop를 실행 하기 전에 조건을 한번 비교하므로 조건이 이미 만족하면 한번도 실행하지 않게 되며 Loop 옆에 조건을 써 주면 Do Loop를 일단 한번 실행하고 조건을 비교 하므로 조건이 이미 만족했다고 하더라도 최소한 1번은 실행하게 된 다. 혼동하기 쉬울 수도 있는 데 아래의 두 코드를 보자.



코드 1

Dim j As Integer
Dim k As Integer

j = True

Do Unitl j
     k = 5
Loop


코드 2

Dim j As Integer
Dim k As Integer

j = True

Do
    k = 5
Loop Until j

'코드 1'을 보면 Do 옆에 조건이 있다. j 에 True를 대입했으므로 Until j를 하면 조건을 만족하게 되므로 Do Loop문 안쪽의 코드를 한번도 실행하지 않고 Loop 다음 문장으로 건너뛰게 된다. 반면 '코드 2'를 보면 Loop 옆 에 조건이 있다. 역시 j에 True를 대입했으므로 Until j를 하면 조건을 만족하게 되나 Do Loop문 안쪽의 코드를 한번은 실행하게 된다. 그래서 결과는 '코드 1'에서는 k가 0이 되지만 '코드 2'에서는 k가 5가 된다. 그렇다면 For Next문과 Do Loop문을 한번 비교해 보자. 먼저 아래는 For Next문으로 1부터 100까지의 합을 구 하는 코드이다.




Dim i As Integer
Dim Tot As Integer

For i = 1 To 100
    Tot = Tot + i
Next

그리고 아래는 Do Loop문으로 1부터 100까지의 합을 구하는 코드이다.




Dim i As Integer
Dim Tot As Integer

Do Until i > 100
    i = i + 1
    Tot = Tot + i
Loop

깜박거리는 폼

그럼 Do Loop문을 사용하는 예제를 보기로 하자. 폼에 아래처럼 커맨드버튼 3개를 위치시키고 속성을 지정한다.

컨트롤 속성 값
Command1 Caption 클릭해 주세요.
Command2 Caption 깜박임 끝
Command3 Caption 종료(&X)

컨트롤	속성	값
Command1	Caption	클릭해 주세요.
Command2	Caption	깜박임 끝
Command3	Caption	종료(&X)

이번에 만들어볼 예제는 '클릭해 주세요.' 버튼을 누르면 폼이 깜박거리고 '깜박임 끝' 버튼을 누르면 깜박임이 멈 추는 것이다. 폼을 깜박이는 방법은 '깜박임 끝' 버튼을 누를 때 까지, 일정 시간을 지연시킨 다음 폼의 색을 번갈 아 바꾸는 작업을 계속 하는 것이다. 그렇다면 '깜박임 끝' 버튼을 누르는 것을 어떻게 감지 할 수 있을까? 이번에 우리가 사용할 방법은 전역변수(프로시져 밖에서 선언한 변수)를 사용해 '깜박임 끝' 버튼이 눌리면 그 변수를 적 절한 값으로 바꾸고 이 값을 기준으로 깜박임을 멈추는 것이다. 먼저 폼을 깜박이는 루틴을 생각해 보자.


Do Until {계속 깜박일 것인지를 결정할 전역변수를 비교하는 조건식}
    If Me.backcolor = vbBlue Then  ' vbBlue는 파란색, vbRed는 빨간색을 뜻하는 상수이다.
        Me.backcolor = vbRed
    Else
        Me.backcolor = vbBlue
    End If
Loop

별 문제가 없어 보인다. 이 코드는 '클릭해 주세요' 버튼을 눌렀을 때 실행되어야 하므로 Command1 의 Click이 벤트를 사용한다. 그럼 폼이 깜박일지를 결정하는 전역변수를 불린형 변수로 선언해서 만약 그 값이 거짓이면 계속 깜박이게 하고 그 값이 참이면 깜박임을 멈추도록 해 보자.


Dim BlinkFlag As Boolean

Private Sub Command1_Click()
  Do Until BlinkFlag
    If Me.backcolor = vbBlue Then
      Me.backcolor = vbRed
    Else
      Me.backcolor = vbBlue
    End If
  Loop
End Sub

그런데 Command1_Click()이 실행되는 시점에서 BlinkFlag는 어떤 값을 가질지 생각해 본 적이 있는가?

변수가 생성된 직후의 값

변수가 선언되면 수치형(Integer, Long, ... 등)은 0으로, 논리형(Boolean)은 False로, 문자형(String)은 ""로 초 기화 된다.

이런 이유에서 BlinkFlag는 False를 값으로 가지며 이 경우 Do Loop문을 계속 실행하게 된다. 그러나 BlinkFlag 가 항상 False일 수는 없다. 왜냐면 '깜박임 끝' 버튼을 눌렀을 때 폼의 깜박임을 멈추기 위해 아래와 같은 코드에 의해 BlinkFlag에 True를 대입하기 때문이다. 즉, 한번 '깜박임 끝' 버튼을 누르면 다음부터는 아무리 '클릭해 주 세요' 버튼을 눌러도 폼이 깜박이지 않는다.


Private Sub Command2_Click()
  BlinkFlag = True
End Sub

그러므로 아래와 같은 코드를 Command1_Click()의 첫 부분에 삽입해, 다시 '클릭해 주세요'를 눌렀을 때 폼이 깜 박이도록 해야 한다.

BlinkFlag = False

아래에 완전한 코드가 있다.


Dim BlinkFlag

Private Sub Command3_Click()
    End
End Sub

Private Sub Command2_Click()
    BlinkFlag = True
End Sub

Private Sub Command1_Click()

    BlinkFlag = False

    Do Until BlinkFlag
        If Me.BackColor = vbBlue Then
            Me.BackColor = vbRed
        Else
            Me.BackColor = vbBlue
        End If
    Loop
    
End Sub

그렇다면 F5를 눌러 실행시킨 다음 '클릭해 주세요' 버튼을 눌러보자. 제대로 되는가? 아... 이게 웬일인지 아무리 '깜박임 끝' 버튼을 눌러도 깜박임이 멈추지 않는다. 그것뿐만이 아니라 폼이 옮겨지지도 않으며 '종료' 버튼도 듣 지 않는다. 침착하게 Ctrl+C를 눌러 프로그램을 끝낸다. 이러한 현상이 나타난 것은 다름아닌 Do Loop문 때문이 다. For Next문이나 Do Loop문 같은 순환문이 실행되고 있는 도중에는 자신의 자원을 윈도즈로 돌려주지 않는다. 그래서 마치 프로그램이 다운된 것처럼 보이기도 하는데 이러한 프로그램은 사용자를 초조하게 만든다. 이제 아래 의 단 한줄을 Do Loop문 사이에 끼워 넣음으로써 이 문제를 해결해 보자.

DoEvents

이 명령어는 프로그램의 제어를 윈도즈에게 넘기는 역할을 한다. 그 사이에 윈도즈는 자신이 처리해야 할 일(키가 눌렸다거나 마우스가 클릭된 것 같은)을 처리하고 다시 제어를 원래대로 되돌려 준다. 이제 프로그램이 먹통이 되 는 것은 바로잡았는데 실행시켜봤다면 알겠지만 색이 무척 빨리 변해서 이건 깜박거리는게 아니라 마치 보라색처 럼 보인다. 임시방편으로 For Next문으로 시간을 지연시키는 코드를 만들자. 이제 Command1_Click()을 아래의 코드처럼 바꾼다.


Private Sub Command1_Click()

    Dim i As Long
    BlinkFlag = False

    Do Until BlinkFlag
        If Me.BackColor = vbBlue Then
            Me.BackColor = vbRed
        Else
            Me.BackColor = vbBlue
        End If
        DoEvents
        For i = 1 To 2000000
        Next
    Loop
    
End Sub

이제 다시 F5를 눌러 실행시켜 보자. '클릭해 주세요' 버튼을 누르면 깜박임도 자연스럽고 프로그램도 먹통이 되지 않으면서 빨간색과 파란색으로 깜박이게 될 것이다.

색상코드 생성기 1

이번에는 스크롤바의 사용법을 익혀보기 위한 예제를 만들어 보겠다. 이 프로그램은 스크롤바를 움직여 원하는 색 을 만들 것이다.

RGB 칼라

RGB는 Red, Green, Blue의 첫자를 모은 것이다. 빛은 R, G, B가 다 모이면 흰색이 나오며 아무것도 없을 때 검 정색이다. VB에서는 R, G, B가 최대치인 상태를 255, 255, 255로 표현한다. 그리고 R, G, B가 최저치인 상태를 0, 0, 0로 표현한다. 그렇다면 표현할 수 있는 색은 256 * 256 * 256의 가지수가 나온다. 이러한 색상을 실제로 사용할 때는 16진수를 사용해서 표현하는데 256은 FF로 표현된다. 16진수로 나타내면 총 여섯자리에 뒷쪽부터 두 자리씩 Red, Green, Blue가 온다. 그렇다면 실제로 몇가지 색을 16진수로 표현해 보자.

색상 상수 16진수 표현
빨간색 vbRed &H0000FF
녹색 vbGreen &H00FF00
파란색 vbBlue &HFF0000
검정색 vbBlack &H000000
흰색 vbWhite &HFFFFFF
노란색 vbYellow &H00FFFF

색상	상수	16진수 표현
빨간색	vbRed	&H0000FF
녹색	vbGreen	&H00FF00
파란색	vbBlue	&HFF0000
검정색	vbBlack	&H000000
흰색	vbWhite	&HFFFFFF
노란색	vbYellow	&H00FFFF

위에서 상수는 비베가 제공하는 색상 코드에 대한 상수이다. 아무래도 직접 16진수를 사용하는 것 보다 상수가 효 율적이다. 16진수 앞쪽에 붙은 "&H"는 "&H" 뒤쪽에 나오는 것이16진수라는 것을 비베에게 알려준다.

RGB() 함수

아무래도 16진수는 인간들이 자주 사용하는 진수체계가 아니라 얼른 생각이 떠오르지 않는다. 그래서 10진수를 16진수로 변환하는 RGB() 함수가 준비되어 있다. 사용법은 아래와 같다.

RGB( 붉은색, 녹색, 파란색 )

물론 붉은색, 녹색, 파란색은 16진수가 아닌 10진수를 기입한다. 예를 들어 흰색을 지정하려면

RGB(255, 255, 255)

로 표현한다.

스크롤 바

스크롤 바 컨트롤에는 수직 스크롤바(Vertical Scrollbar)와 수평 스크롤바(Horizontal Scrollbar)가 있다. 여기서는 수평 스크롤바를 대상으로 설명하겠다. 방향만 수직, 수평으로 다를 뿐 나머지는 차이가 없다.

Max: 슬라이더가 오른쪽에 붙어 있을 때 스크롤바가 갖는 최대값이다.
Min: 슬라이더가 왼쪽에 붙어 있을 때 스크롤바가 갖는 최소값이다.
LargeChange: 스크롤바에서 슬라이더와 화살표버튼을 제외한 영역을 클릭했을 때 움직일 값
SmallChange: 스크롤바의 화살표버튼을 클릭했을 때 움직일 값
Value: 현재 슬라이더가 머물고 있는 위치의 값
Change(): 스크롤바의 슬라이더가 움직이면 Change 이벤트가 발생한다. 그리고 스크롤바의 Value 속성이 변화하게 된다.

아무래도 설명이 좀 이해하기 어렵게 된 것 같다. 뭐라고 설명하기가 곤란한 부분인데 직접 해보면서 익혀보도록 하자.

색상코드 생성기

아래처럼 레이블 5개, 스크롤바 3개, 커맨드버튼 1개를 위치시키고 각각의 속성을 지정한다.

컨트롤 속성 값
Label1 Caption Red:
Label2 Caption Green:
Label3 Caption Blue:
Label4 Caption 미리보기:
Label5 Caption {없음}
Appearance 0 - 기본
BorderStyle 1 - 단일 고정
HScroll1 Max 255
HScroll2 Max 255
HScroll3 Max 255
Command1 Caption 종료(&X)

컨트롤	속성	값
Label1	Caption	Red:
Label2	Caption	Green:
Label3	Caption	Blue:
Label4	Caption	미리보기:
Label5	Caption	{없음}
Appearance	0 - 기본
BorderStyle	1 - 단일 고정
HScroll1	Max	255
HScroll2	Max	255
HScroll3	Max	255
Command1	Caption	종료(&X)

목적은 스크롤바의 슬라이더를 움직이면 Label5의 색을 변화시키면서 바로 현재의 색을 알 수 있게 하는 것이다. 위쪽에서 스크롤바의 슬라이더를 움직이면 Change 이벤트가 발생하면서 Value 속성이 변한다고 설명했었다. 그리 고 스크롤바들은 현재 최소값(MinValue)이 0, 최대값(MaxValue)이 255로 설정되어 있기 때문에 Value 속성의 값 은 이 범위를 벗어날 수 없다. 즉, Value의 최소값은 0이며 최대값은 255이다. 이것은 RGB 코드에서 한 색상값 의 범위와 일치한다. 이것을 RGB() 함수를 사용해 아래와 같이 표현할 수 있다.

Label5.BackColor = RGB(HScroll1.Value, HScroll2.Value, HScroll3.Value)

또한 스크롤바의 슬라이더 위치가 변하면 Change 이벤트가 발생하므로 위의 코드를 각 스크롤바의 Change 이벤 트에 삽입해 주면 된다. 완성된 코드는 다음과 같다.


Private Sub Command1_Click()
    End
End Sub

Private Sub HScroll1_Change()
    Label5.BackColor = RGB(HScroll1.Value, HScroll2.Value, HScroll3.Value)
End Sub

Private Sub HScroll2_Change()
    Label5.BackColor = RGB(HScroll1.Value, HScroll2.Value, HScroll3.Value)
End Sub

Private Sub HScroll3_Change()
    Label5.BackColor = RGB(HScroll1.Value, HScroll2.Value, HScroll3.Value)
End Sub

아래는 이 예제를 실행한 모습이다.